VFN_StartSession()

       // Example Program: T_STRSES
       // Description:
       //   This is a test program to illustrate how to call the
       //   VFN_StartSession() subprocedure. This subprocedure opens a session
       //   on the device which is required for all payment and line item
       //   transactions. When this is complete, you should call
       //   VFN_EndSession() (demonstrated in example program T_ENDSES).

       Ctl-Opt DftActGrp(*No) ActGrp(*Caller) BndDir('PTTIBND');

       /COPY QRPGLECPY,VFNCB

       // This is included for demo output purposes.
       Dcl-Pr WriteToJobLog Int(10) Extproc('Qp0zLprintf');
         pString Pointer Value Options(*String);
       End-Pr;
       Dcl-C NewLine x'15';

       // This will capture returned error information
       Dcl-Ds ErrorDS LikeDS(VFN_ErrorDS_t) Inz(*LikeDS);
       // This will be used to pass request information to the API call
       Dcl-Ds StrSesReqDS LikeDS(VFN_StartSessionReqDS_t) Inz(*LikeDS);
       // This will store parsed response data from the API call
       Dcl-Ds StrSesRspDS LikeDS(VFN_StartSessionRspDS_t) Inz(*LikeDS);

       reset ErrorDS;
       reset StrSesReqDS;
       reset StrSesRspDS;

       // This must be a device that has already been successfully registered
       //  with VFN_Register() and which exists in VFNDVC.
       StrSesReqDS.DeviceID = 'test';

       // These fields can be assigned a log file name, and will write the
       //  request and response xml data to the logging directory.
       StrSesReqDS.RequestLog = 'T_STRSES_Request.xml';
       StrSesReqDS.ResponseLog = 'T_STRSES_Response.xml';

       // This data structure should be populated per the Verifone documentation
       //  and many of the fields are considered optional.
       StrSesReqDS.Invoice = '1';
       StrSesReqDS.StoreNum = '';
       StrSesReqDS.Lane = '';
       StrSesReqDS.CashierID = '';
       StrSesReqDS.ServerID = '';
       StrSesReqDS.ShiftID = '';
       StrSesReqDS.TableNum = '';
       StrSesReqDS.BusinessDate = %Date();
       StrSesReqDS.PurchaseID = '';

       // if VFN_StartSession() returns *Off, it means that an error occurred
       //  as part of the overall communication process, and the information
       //  will be in ErrorDS - ErrorDS.Message is the main field to look at
       //  for troubleshooting.
       if not VFN_StartSession( StrSesReqDS : StrSesRspDS : ErrorDS );
         // handle error
         WriteToJobLog( 'Message ID: ' + ErrorDS.MessageId + NewLine );
         WriteToJobLog( 'Message: ' + ErrorDS.Message + NewLine );
         *INLR = *On;
         return;
       else;
         // Now you can check the response data structure for any status info
         //  or data returned from the device:
         WriteToJobLog( 'Response Text: '
                      + StrSesRspDS.ResponseText + NewLine );

         WriteToJobLog( 'Result: ' + StrSesRspDS.Result + NewLine );

         WriteToJobLog( 'Response Code: '
                      + StrSesRspDS.ResultCode + NewLine );

         WriteToJobLog( 'Termination Status: '
                      + StrSesRspDS.TerminationStatus + NewLine );
       endif;

       *INLR = *On;
       return;