RXS_ParseDomToDom()

**FREE
// This example demonstrates starting a DOM parsing session by using
//  RXS_OpenDom and then retrieving a subsection of the DOM structure. This is
//  usually helpful when working with large documents as it can make it easier
//  to specify the correct XPaths to work with the sections of the document
//  that you want to reach. It's important to call RXS_CloseDom once DOM
//  parsing has been completed to free memory used by the DOM parser.

Ctl-Opt ActGrp(*New) BndDir('RXSBND');

/COPY QRPGLECPY,RXSCB

Dcl-Ds RootDomDS LikeDS(RXS_ParseDomDS_t);
Dcl-Ds BookDomDS LikeDS(RXS_ParseDomDS_t);
Dcl-S XPath Like(RXS_Var8Kv_t);
Dcl-S Data Like(RXS_Var1Kv_t);

Dcl-S x Uns(10);

Dcl-S gXML Like(RXS_Var64Kv_t);

gXML = '<?xml version="1.0" encoding="UTF-8"?>'
     + '<bookstore xmlns:test="testnamespace">'
     + '<book category="children">'
     + '<title lang="en"><![CDATA[Charlotte''s Web]]></title>'
     + '<author>E. B. White</author>'
     + '<year>1952</year>'
     + '<price>5.99</price>'
     + '<review><text>What a great book!</text></review>'
     + '<review><text>Highly recommended.</text></review>'
     + '</book>'
     + '<book category="cooking">'
     + '<title lang="en">Everyday Italian</title>'
     + '<author>Giada De Laurentiis</author>'
     + '<year>2005</year>'
     + '<price>30.00</price>'
     + '</book>'
     + '</bookstore>';

RXS_ResetDS( RootDomDS : RXS_DS_TYPE_PARSEDOM );

RootDomDS = RXS_OpenDom( gXML );

XPath = RXS_XPath( '/*:bookstore/*:book' );
RXS_ResetDS( BookDomDS : RXS_DS_TYPE_PARSEDOM );
BookDomDS = RXS_ParseDomToDom( XPath : RootDomDS );

// Any subsequent XPaths used to query BookDomDS no longer
//  need to include the /*:bookstore/ portion of the XPath.
for x = 1 to BookDomDS.NodeCount;
  XPath = RXS_XPath( '*:book[%u]/*:title' : x );
  Data = RXS_ParseDomToText( XPath : BookDomDS );
  RXS_JobLog( 'Title: %s' : Data );
  // This will output:
  // Title: Charlotte's Web
  // Title: Everyday Italian
endfor;

RXS_CloseDom( RootDomDS );

return;