// Example Program: T_CAPPRT
// Description:
// This is a test program to illustrate how to call the CTI_Run()
// subprocedure to perform a partial capture on a previous authorization.
//
// To achieve this, generate a unique ID with CTI_NextUniqueId() and
// then populate and write a record to CTIWSHDR. Then, call CTI_Run()
// passing in your unique ID as well as the other parameters shown.
//
// CTI_Run() will return *On if no error was encountered, or *Off
// if an error occurred. If an error occurred, you should look at
// the fields in ErrorDS to retrieve information about the error.
//
// Otherwise, you can perform a CHAIN against the CTIWSRSP physical
// file, and retrieve the result fields.
Ctl-Opt ActGrp(*Caller) BndDir('CTIBND') Option(*NoDebugIO);
Dcl-F CTIWSHDR Disk(*Ext) Keyed Qualified Usage(*Input:*Output);
Dcl-F CTIWSITM Disk(*Ext) Keyed Qualified Usage(*Input:*Output);
Dcl-F CTIWSRSP Disk(*Ext) Keyed Qualified Usage(*Input);
Dcl-Ds HDR ExtName('CTIWSHDR':*Output) Qualified End-Ds;
Dcl-Ds ITM ExtName('CTIWSITM':*Output) Qualified End-Ds;
Dcl-Ds RSP ExtName('CTIWSRSP':*Input) Qualified End-Ds;
/COPY QRPGLECPY,CTICB
// This is included for demo output purposes.
Dcl-Pr WriteToJobLog Int(10) Extproc('Qp0zLprintf');
pString Pointer Value Options(*String);
End-Pr;
Dcl-C NewLine x'15';
// This stores the unique ID for this API call
Dcl-S UniqueId Like(CTI_UniqueId_t) Inz;
// This holds any error information returned by the API call
Dcl-Ds ErrorDS LikeDS(CTI_ErrorDS_t) Inz(*LikeDS);
// Modify this field to use your merchant ID
Dcl-S MerchantId Like(CTI_MerchantId_t) Inz('ikrengel');
reset ErrorDS;
// Each API call requires a unique ID
UniqueId = CTI_NextUniqueId();
// CTIWSHDR needs to be populated with the transaction data
clear HDR;
HDR.UID = UniqueId;
HDR.CRTDT = %Timestamp();
HDR.CAPRUN = CTI_TRUE;
HDR.MCHID = MerchantId;
HDR.MCHREFCD = 'MYREFCD134';
// This value is returned by a previous authorization operation.
// That authorization may have been performed against a credit card,
// or with a digital wallet like Apple Pay or Visa Checkout. The
// value for this request ID will be found in CTIWSRSP.REQID if the
// authorization was performed with a call to CTI_Run().
HDR.ATHREQID = '3379....056442';
HDR.CAPPCHLVL = '';
HDR.MCHDSCR = 'asdf';
HDR.PTCUR = 'USD';
// The sum total of all partial captures against an authorization must
// not exceed the initial grand total amount
HDR.PTGNDAMT = '1.00';
HDR.PTTAXAMT = '0.10';
HDR.VBLATHCD = '';
// Partial capture fields
// This field should be incremented for each partial capture
HDR.PPCAPSQNCE = '2';
// CyberSource recommends setting this to '99' if you do not know the
// exact number of captures
// This must be set to the correct value on the final capture
HDR.PPCAPTOTCT = '99';
// Value from CTIWSRSP.REQTK
HDR.ORDREQTK = 'Ahj/7wSRbltU3vE...tSCz';
write CTIWSHDR.CTIWSHDRR HDR;
clear ITM;
ITM.PID = UniqueId;
ITM.UID = CTI_NextUniqueId;
ITM.CRTDT = %Timestamp();
ITM.PRDCD = 'Default';
ITM.QTY = 1;
ITM.UNTPRC = '1.00';
ITM.TAXAMT = '.1';
ITM.SEQ# = 1;
write CTIWSITM.CTIWSITMR ITM;
clear ITM;
ITM.PID = UniqueId;
ITM.UID = CTI_NextUniqueId();
ITM.CRTDT = %Timestamp();
ITM.PRDCD = 'Default';
ITM.QTY = 1;
ITM.UNTPRC = '1.00';
ITM.TAXAMT = '.10';
ITM.SEQ# = 2;
write CTIWSITM.CTIWSITMR ITM;
if not CTI_Run( UniqueId : ErrorDS : *Omit : *Omit : MerchantId );
// If CTI_Run() returns *Off then an error occured.
// You should check ErrorDS subfields for info:
// ErrorDS.Subproc = Name of CTI subprocedure that threw error
// ErrorDS.MessageId = Message ID of the error message
// ErrorDS.Message = Error message description
// ErrorDS.LogFile = Path to a log file created in the IFS that can
// be used for troubleshooting. Log files are generated
// automatically whenever an error occurs. You can also force log
// files to generate by modifying the value of the LOGALL field in
// CTICFGMCH for the provided Merchant ID.
// ErrorDS.Source =
// - CTI_SOURCE_INTERNAL is a general product error.
// This could be due to issues with input data, or the
// inability to access physical files, etc.
//
// - CTI_SOURCE_TRANSMIT is a product error that specifically
// occurred during HTTPS communication with the CyberSource
// webservice. This could be due to issues with your network
// configuration, proxy setup, internet connection, etc.
//
// - CTI_SOURCE_REMOTE is an error message provided by CyberSource.
WriteToJobLog( 'Error Message Id: ' + ErrorDS.MessageId + NewLine );
WriteToJobLog( 'Error Message: ' + ErrorDS.Message + NewLine );
WriteToJobLog( 'Error Source: ' + ErrorDS.Source + NewLine );
// All error information is also written to the file CTIERR.
else;
// If CTI_Run() returned *On the request was successful. You can
// access the results in the CTIWSRSP file using the same UniqueID
// that was used to create the request record in CTIWSRSP.
chain UniqueId CTIWSRSP.CTIWSRSPR RSP;
if %Found(CTIWSRSP);
// For this sample code we're writing the response data to the job
// log, but generally you would extract the data and pass it into
// your own data tables. The CTIWSHDR, CTIWSITM, and CTIWSRSP files
// should not be used for long-term data storage and should instead
// be considered short-term transactional files.
// Capture Response fields
WriteToJobLog( 'MCHREFCD: ' + RSP.MCHREFCD + NewLine );
WriteToJobLog( 'CAPAMT: ' + RSP.CAPAMT + NewLine );
WriteToJobLog( 'RSNCD: ' + %Char(RSP.RSNCD) + NewLine );
WriteToJobLog( 'CAPRSNCD: ' + %Char(RSP.CAPRSNCD) + NewLine );
WriteToJobLog( 'REQID: ' + RSP.REQID + NewLine );
WriteToJobLog( 'REQTK: ' + RSP.REQTK + NewLine );
WriteToJobLog( 'CAPREQDT: ' + RSP.CAPREQDT + NewLine );
WriteToJobLog( 'CAPRECID: ' + RSP.CAPRECID + NewLine );
endif;
endif;
*INLR = *On;
return;