// Example Program: T_ATHCAP
// Description:
// This is a test program to illustrate how to call the CTI_Run()
// subprocedure to perform an authorization and then capture
//
// To achieve this, generate a unique ID with CTI_NextUniqueId(), and
// then populate and write a record to CTIWSHDR. This example also
// writes one or more records to CTIWSITM to provide that level of
// detail. Then, call CTI_Run() passing in your unique ID as well
// as the other parameters shown.
//
// CTI_Run() will return *On if no error was encountered, or *Off
// if an error occurred. If an error occurred, you should look at
// the fields in ErrorDS to retrieve information about the error.
//
// Otherwise, you can perform a CHAIN against the CTIWSRSP physical
// file, and retrieve the result fields.
Ctl-Opt ActGrp(*Caller) BndDir('CTIBND') Option(*NoDebugIO);
Dcl-F CTIWSHDR Disk(*Ext) Keyed Qualified Usage(*Input:*Output);
Dcl-F CTIWSITM Disk(*Ext) Keyed Qualified Usage(*Input:*Output);
Dcl-F CTIWSRSP Disk(*Ext) Keyed Qualified Usage(*Input);
Dcl-Ds HDR ExtName('CTIWSHDR':*Output) Qualified End-Ds;
Dcl-Ds ITM ExtName('CTIWSITM':*Output) Qualified End-Ds;
Dcl-Ds RSP ExtName('CTIWSRSP':*Input) Qualified End-Ds;
/COPY QRPGLECPY,CTICB
// This is included for demo output purposes.
Dcl-Pr WriteToJobLog Int(10) Extproc('Qp0zLprintf');
pString Pointer Value Options(*String);
End-Pr;
Dcl-C NewLine x'15';
// This stores the unique ID for this API call
Dcl-S UniqueId Like(CTI_UniqueId_t) Inz;
// This holds any error information returned by the API call
Dcl-Ds ErrorDS LikeDS(CTI_ErrorDS_t) Inz(*LikeDS);
// Modify this field to specify different card details
Dcl-S CardNumber Char(20) Inz('4111111111111111');
// Modify this field to use your merchant ID
Dcl-S MerchantId Like(CTI_MerchantId_t) Inz('ikrengel');
reset ErrorDS;
// Each API call requires a unique ID
UniqueId = CTI_NextUniqueId();
// CTIWSHDR needs to be populated with the transaction data
clear HDR;
HDR.UID = UniqueId;
HDR.CRTDT = %Timestamp();
HDR.ATHRUN = CTI_TRUE;
HDR.CAPRUN = CTI_TRUE;
HDR.MCHID = MerchantId;
HDR.MCHREFCD = 'MYREFCD132';
HDR.CAPPCHLVL = '';
HDR.CCCRDTYP = '001';
HDR.CCEXPMM = '10';
HDR.CCEXPYY = '2021';
HDR.BTFNAM = 'Jim';
HDR.BTLNAM = 'Jones';
HDR.BTST1 = '123 Central';
HDR.BTCTY = 'Mankato';
HDR.BTSTT = 'MN';
HDR.BTPSTCD = '56001';
HDR.BTCNTRY = 'US';
HDR.BTEML = 'asdf@asdf.com';
HDR.STST1 = '123 Central';
HDR.STCTY = 'Mankato';
HDR.STSTT = 'MN';
HDR.STPSTCD = '56001';
HDR.STCNTRY = 'US';
HDR.USRPO = 'something important';
HDR.MCHDSCR = 'Merchant Description from me';
HDR.PTCUR = 'USD';
HDR.PTGNDAMT = '3.03';
HDR.PTTAXAMT = '.75';
HDR.VBLATHCD = '';
HDR.ORDREQTK = '';
write CTIWSHDR.CTIWSHDRR HDR;
clear ITM;
ITM.PID = UniqueId;
ITM.UID = CTI_NextUniqueId();
ITM.CRTDT = %Timestamp();
ITM.COMMCD = '';
ITM.PRDCD = 'Default';
ITM.QTY = 1;
ITM.UNTPRC = '1.00';
ITM.TAXAMT = '.10';
ITM.SEQ# = 1;
write CTIWSITM.CTIWSITMR ITM;
clear ITM;
ITM.PID = UniqueId;
ITM.UID = CTI_NextUniqueId();
ITM.CRTDT = %Timestamp();
ITM.COMMCD = '';
ITM.PRDCD = 'Default';
ITM.QTY = 1;
ITM.UNTPRC = '2.00';
ITM.TAXAMT = '.20';
ITM.SEQ# = 2;
write CTIWSITM.CTIWSITMR ITM;
if not CTI_Run( UniqueId : ErrorDS : CardNumber : *Omit : MerchantId );
// If CTI_Run() returns *Off then an error occured.
// You should check ErrorDS subfields for info:
// ErrorDS.Subproc = Name of CTI subprocedure that threw error
// ErrorDS.MessageId = Message ID of the error message
// ErrorDS.Message = Error message description
// ErrorDS.LogFile = Path to a log file created in the IFS that can
// be used for troubleshooting. Log files are generated
// automatically whenever an error occurs. You can also force log
// files to generate by modifying the value of the LOGALL field in
// CTICFGMCH for the provided Merchant ID.
// ErrorDS.Source =
// - CTI_SOURCE_INTERNAL is a general product error.
// This could be due to issues with input data, or the
// inability to access physical files, etc.
//
// - CTI_SOURCE_TRANSMIT is a product error that specifically
// occurred during HTTPS communication with the CyberSource
// webservice. This could be due to issues with your network
// configuration, proxy setup, internet connection, etc.
//
// - CTI_SOURCE_REMOTE is an error message provided by CyberSource.
WriteToJobLog( 'Error Message Id: ' + ErrorDS.MessageId + NewLine );
WriteToJobLog( 'Error Message: ' + ErrorDS.Message + NewLine );
WriteToJobLog( 'Error Source: ' + ErrorDS.Source + NewLine );
// All error information is also written to the file CTIERR.
else;
// If CTI_Run() returned *On the request was successful. You can
// access the results in the CTIWSRSP file using the same UniqueID
// that was used to create the request record in CTIWSRSP.
chain UniqueId CTIWSRSP.CTIWSRSPR RSP;
if %Found(CTIWSRSP);
// For this sample code we're writing the response data to the job
// log, but generally you would extract the data and pass it into
// your own data tables. The CTIWSHDR, CTIWSITM, and CTIWSRSP files
// should not be used for long-term data storage and should instead
// be considered short-term transactional files.
// Authorization Response fields
WriteToJobLog( 'CCAMT: ' + RSP.CCAMT + NewLine );
WriteToJobLog( 'CCATHCD: ' + RSP.CCATHCD + NewLine );
WriteToJobLog( 'CCATHDT: ' + RSP.CCATHDT + NewLine );
WriteToJobLog( 'RSNCD: ' + %Char(RSP.RSNCD) + NewLine );
WriteToJobLog( 'CCRSNCD: ' + RSP.CCRSNCD + NewLine );
WriteToJobLog( 'REQID: ' + RSP.REQID + NewLine );
WriteToJobLog( 'REQTK: ' + RSP.REQTK + NewLine );
WriteToJobLog( 'CCAVSCD: ' + RSP.CCAVSCD + NewLine );
WriteToJobLog( 'CCAVSCDR: ' + RSP.CCAVSCDR + NewLine );
WriteToJobLog( 'CCPRCRSP: ' + RSP.CCPRCRSP + NewLine );
// Capture Response fields
WriteToJobLog( 'MCHREFCD: ' + RSP.MCHREFCD + NewLine );
WriteToJobLog( 'CAPAMT: ' + RSP.CAPAMT + NewLine );
WriteToJobLog( 'RSNCD: ' + %Char(RSP.RSNCD) + NewLine );
WriteToJobLog( 'CAPRSNCD: ' + %Char(RSP.CAPRSNCD) + NewLine );
WriteToJobLog( 'REQID: ' + RSP.REQID + NewLine );
WriteToJobLog( 'REQTK: ' + RSP.REQTK + NewLine );
WriteToJobLog( 'CAPREQDT: ' + RSP.CAPREQDT + NewLine );
WriteToJobLog( 'CAPRECID: ' + RSP.CAPRECID + NewLine );
endif;
endif;
*INLR = *On;
return;