UPS_shipAccept()

 *------------------------------------------------------------------------
 * @Author: Kato Integrations
 * @Description:
 *   This is a test program to illustrate how to call the
 *   UPS_shipAccept() subprocedure to finalize a shipment.
 *
 *   To achieve this, pass the same UniqueID that was passed to a prior
 *   UPS_shipConfirm() call to UPS_shipAccept(). UPS_shipAccept() does
 *   not have request data tables, only response data tables.
 *
 *   UPS_shipAccept() will return *On if no error was encountered,
 *   or *Off if an error occurred. If an error occurred, you should
 *   look at the fields in ErrorDS to retrieve information about the
 *   error.
 *
 *   Otherwise, you can read the result data from UPSSARS and UPSSARSPK.
 *------------------------------------------------------------------------
H DFTACTGRP(*NO) ACTGRP(*NEW) BNDDIR('UPSBND') OPTION(*NODEBUGIO)

FUPSSARS   IF A E           K DISK    Qualified
FUPSSARSPK IF A E           K DISK    Qualified

 /COPY QRPGLECPY,UPS

 // This is included for demo output purposes.
D WriteToJobLog   PR            10I 0 Extproc('Qp0zLprintf')
D  pString                        *   Value Options(*String)
D NewLine         C                   x'15'

D SARS            DS                  Likerec(UPSSARS.RUPSSARS:*Input)
D SARSPK          DS                  Likerec(UPSSARSPK.RUPSSARSPK:*Input)

D ErrorDS         DS                  LikeDS(UPS_ErrorDS_t) Inz(*LikeDS)

D UniqueID        S                   Like(UPS_UniqueID_t)
 /FREE
  reset ErrorDS;

  // Replace this with a UniqueID previously used to call
  //  UPS_shipConfirm()
  UniqueID = 1;

  // If UPS_shipAccept() returns *Off, an error occurred and
  //  UPS_ErrorDS should be reviewed to determine the cause.
  if not UPS_shipAccept( UniqueID : ErrorDS );
    WriteToJobLog( 'API Error: ' + NewLine );
    WriteToJobLog( 'Error Code: ' + %Trim(ErrorDS.Code) + NewLine );
    WriteToJobLog( 'Error Severity: ' +
                   %Char(ErrorDS.Severity) + NewLine );
    WriteToJobLog( 'Error Source: ' + %Trim(ErrorDS.Pgm) + NewLine );
    WriteToJobLog( 'Error Text: ' + %Trim(ErrorDS.Text) + NewLine );
    exsr cleanup;
    return;
  else;

    // Read the results from UPSSARS. There is only going to be one record
    chain UniqueID UPSSARS.RUPSSARS SARS;
    if not %Found(UPSSARS);
      WriteToJobLog( 'ERROR: No results found in UPSSARS' + NewLine );
      exsr cleanup;
      return;
    endif;

    WriteToJobLog( 'Result Record: ' + NewLine );
    WriteToJobLog( 'UID: ' + %Char(SARS.UID) + NewLine );
    WriteToJobLog( 'SHIPNBR: ' + %Trim(SARS.SHIPNBR) + NewLine );
    WriteToJobLog( 'WGTCD: ' + %Trim(SARS.WGTCD) + NewLine );
    WriteToJobLog( 'TOTWGT: ' + %Char(SARS.TOTWGT) + NewLine );
    WriteToJobLog( 'TRSCURCD: ' + %Trim(SARS.TRSCURCD) + NewLine );
    WriteToJobLog( 'TRSCHRG: ' + %Char(SARS.TRSCHRG) + NewLine );
    WriteToJobLog( 'SVCCURCD: ' + %Trim(SARS.SVCCURCD) + NewLine );
    WriteToJobLog( 'SVCCHRG: ' + %Char(SARS.SVCCHRG) + NewLine );
    WriteToJobLog( 'TOTCURCD: ' + %Trim(SARS.TOTCURCD) + NewLine );
    WriteToJobLog( 'TOTCHRG: ' + %Char(SARS.TOTCHRG) + NewLine );
    WriteToJobLog( 'NEGCURCD: ' + %Trim(SARS.NEGCURCD) + NewLine );
    WriteToJobLog( 'NEGCHRG: ' + %Char(SARS.NEGCHRG) + NewLine );


    // Next you could read through UPSSARSPK to get package-level info
    //  such as the tracking number, individual service charges, etc.
    //  Most importantly, this is where you'd find the IFS path of
    //  the label you have requested from UPS. If you have requested
    //  a ZPL label, you can then call UPS_printZPL() to print the
    //  label to a spooled file which can then be sent to a
    //  ZPL-compatible printer.
    chain UniqueID UPSSARSPK.RUPSSARSPK SARSPK;
    if not %Found(UPSSARSPK);
      WriteToJobLog( 'ERROR: No results found in UPSSARSPK' + NewLine );
      exsr cleanup;
      return;
    endif;

    dow not %Eof(UPSSARSPK);
      WriteToJobLog( 'Result Record: ' + NewLine );
      WriteToJobLog( 'UID: ' + %Char(SARSPK.UID) + NewLine );
      WriteToJobLog( 'TRACKNBR: ' + %Trim(SARSPK.TRACKNBR) + NewLine );
      WriteToJobLog( 'LBLFMT: ' + %Trim(SARSPK.LBLFMT) + NewLine );
      WriteToJobLog( 'LBLPATH: ' + %Trim(SARSPK.LBLIMG) + NewLine );
      WriteToJobLog( 'SVCCURCD: ' + %Trim(SARSPK.SVCCURCD) + NewLine );
      WriteToJobLog( 'SVCCHRG: ' + %Char(SARSPK.SVCCHRG) + NewLine );
      WriteToJobLog( '==========' + NewLine );
      reade UniqueID UPSSARSPK.RUPSSARSPK SARSPK;
    enddo;
  endif;

  exsr cleanup;
  return;

  begsr cleanup;
    // Always call UPS_cleanup() any time your program will terminate
    UPS_cleanup();
    *INLR = *ON;
  endsr;

 /END-FREE