VFN_GetDeviceName()

       // Example Program: T_GETNAME
       // Description:
       //   This is a test program to illustrate how to call the
       //   VFN_GetDeviceName() subprocedure. This retrieves the name of the
       //   specified device.
       //
       //   Note that this requires the devnameenabled parameter to be enabled
       //   in config.usrl on your device.

       Ctl-Opt DftActGrp(*No) ActGrp(*Caller) BndDir('PTTIBND');

       /COPY QRPGLECPY,VFNCB

       // This is included for demo output purposes.
       Dcl-Pr WriteToJobLog Int(10) Extproc('Qp0zLprintf');
         pString Pointer Value Options(*String);
       End-Pr;
       Dcl-C NewLine x'15';

       // This will capture returned error information
       Dcl-Ds ErrorDS LikeDS(VFN_ErrorDS_t) Inz(*LikeDS);
       // This will be used to pass request information to the API call
       Dcl-Ds GetNameReqDS LikeDS(VFN_GetDeviceNameReqDS_t) Inz(*LikeDS);
       // This will store parsed response data from the API call
       Dcl-Ds GetNameRspDS LikeDS(VFN_GetDeviceNameRspDS_t) Inz(*LikeDS);

       reset ErrorDS;
       reset GetNameReqDS;
       reset GetNameRspDS;

       // This must be a device that has already been successfully registered
       //  with VFN_Register() and which exists in VFNDVC.
       GetNameReqDS.DeviceID = 'test';

       // if VFN_GetDeviceName() returns  //Off, it means that an error occurred
       //  as part of the overall communication process, and the information
       //  will be in ErrorDS - ErrorDS.Message is the main field to look at
       //  for troubleshooting.
       if not VFN_GetDeviceName( GetNameReqDS : GetNameRspDS : ErrorDS );
         // handle error
         WriteToJobLog( 'Message ID: ' + ErrorDS.MessageId + NewLine );
         WriteToJobLog( 'Message: ' + ErrorDS.Message + NewLine );
         *INLR = *On;
         return;
       else;
         // Now you can check the response data structure for any status info
         //  or data returned from the device:
         WriteToJobLog( 'Response Text: '
                      + GetNameRspDS.ResponseText + NewLine );

         WriteToJobLog( 'Result: ' + GetNameRspDS.Result + NewLine );

         WriteToJobLog( 'Response Code: '
                      + GetNameRspDS.ResultCode + NewLine );

         WriteToJobLog( 'Termination Status: '
                      + GetNameRspDS.TerminationStatus + NewLine );

         WriteToJobLog( 'DeviceName: '
                      + GetNameRspDS.DeviceName + NewLine );

         WriteToJobLog( 'MAC Labels: '
                      + GetNameRspDS.MACLabels + NewLine );
         // Please see QRPGLECPY,VFNCB for the other fields
         //  in VFN_GetDeviceNameReqDS_t
       endif;

       *INLR = *On;
       return;